Use AX_PROG_CC_FOR_BUILD macro to identify compiler targeting the build host.

(When cross-compiling, this is *not* the compiler used to build wireshark itself).

Macro ax_prog_cc_for_build.m4 retrieved from http://git.savannah.gnu.org/gitweb/?p=autoconf-archive.git

Change-Id: I035059d9315e0081dcf1ffbafd9ce6d7ad46700c
Reviewed-on: https://code.wireshark.org/review/4503
Petri-Dish: Alexis La Goutte <alexis.lagoutte@gmail.com>
Tested-by: Petri Dish Buildbot <buildbot-no-reply@wireshark.org>
Reviewed-by: Eric Anderson <andersoe@cs.cmu.edu>
Reviewed-by: João Valverde <j@v6e.pt>

5 files changed, 144 insertions, 21 deletions

diff --git a/Makefile.am b/Makefile.am
index a9dc3c9894..f4230ddeab 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -711,6 +711,7 @@ EXTRA_DIST = \
 	aclocal-fallback/ax_ext.m4			\
 	aclocal-fallback/ax_gcc_x86_cpuid.m4		\
 	aclocal-fallback/ax_gcc_x86_avx_xgetbv.m4	\
+	aclocal-fallback/ax_prog_cc_for_build.m4	\
 	aclocal-fallback/libsmi.m4			\
 	aclocal-fallback/libgcrypt.m4			\
 	aclocal-flags		\
diff --git a/acinclude.m4 b/acinclude.m4
index b432d4cea2..81d385e043 100644
--- a/acinclude.m4
+++ b/acinclude.m4
@@ -1622,7 +1622,7 @@ if test "x$ac_supports_gcc_flags" = "xyes" ; then
                 # with which we're building Wireshark, so add the flags
                 # to the flags for that compiler as well.
                 #
-                CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
+                AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS_FOR_BUILD])
               fi
             ],
             [
@@ -1641,7 +1641,7 @@ if test "x$ac_supports_gcc_flags" = "xyes" ; then
             # with which we're building Wireshark, so add the flags
             # to the flags for that compiler as well.
             #
-            CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD $GCC_OPTION"
+            AX_APPEND_FLAG([$GCC_OPTION], [WS_CFLAGS_FOR_BUILD])
           fi
         fi
       ],
diff --git a/aclocal-fallback/ax_prog_cc_for_build.m4 b/aclocal-fallback/ax_prog_cc_for_build.m4
new file mode 100644
index 0000000000..77fd346a79
--- /dev/null
+++ b/aclocal-fallback/ax_prog_cc_for_build.m4
@@ -0,0 +1,125 @@
+# ===========================================================================
+#   http://www.gnu.org/software/autoconf-archive/ax_prog_cc_for_build.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_PROG_CC_FOR_BUILD
+#
+# DESCRIPTION
+#
+#   This macro searches for a C compiler that generates native executables,
+#   that is a C compiler that surely is not a cross-compiler. This can be
+#   useful if you have to generate source code at compile-time like for
+#   example GCC does.
+#
+#   The macro sets the CC_FOR_BUILD and CPP_FOR_BUILD macros to anything
+#   needed to compile or link (CC_FOR_BUILD) and preprocess (CPP_FOR_BUILD).
+#   The value of these variables can be overridden by the user by specifying
+#   a compiler with an environment variable (like you do for standard CC).
+#
+#   It also sets BUILD_EXEEXT and BUILD_OBJEXT to the executable and object
+#   file extensions for the build platform, and GCC_FOR_BUILD to `yes' if
+#   the compiler we found is GCC. All these variables but GCC_FOR_BUILD are
+#   substituted in the Makefile.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved. This file is offered as-is, without any
+#   warranty.
+
+#serial 8
+
+AU_ALIAS([AC_PROG_CC_FOR_BUILD], [AX_PROG_CC_FOR_BUILD])
+AC_DEFUN([AX_PROG_CC_FOR_BUILD], [dnl
+AC_REQUIRE([AC_PROG_CC])dnl
+AC_REQUIRE([AC_PROG_CPP])dnl
+AC_REQUIRE([AC_EXEEXT])dnl
+AC_REQUIRE([AC_CANONICAL_HOST])dnl
+
+dnl Use the standard macros, but make them use other variable names
+dnl
+pushdef([ac_cv_prog_CPP], ac_cv_build_prog_CPP)dnl
+pushdef([ac_cv_prog_gcc], ac_cv_build_prog_gcc)dnl
+pushdef([ac_cv_prog_cc_works], ac_cv_build_prog_cc_works)dnl
+pushdef([ac_cv_prog_cc_cross], ac_cv_build_prog_cc_cross)dnl
+pushdef([ac_cv_prog_cc_g], ac_cv_build_prog_cc_g)dnl
+pushdef([ac_cv_exeext], ac_cv_build_exeext)dnl
+pushdef([ac_cv_objext], ac_cv_build_objext)dnl
+pushdef([ac_exeext], ac_build_exeext)dnl
+pushdef([ac_objext], ac_build_objext)dnl
+pushdef([CC], CC_FOR_BUILD)dnl
+pushdef([CPP], CPP_FOR_BUILD)dnl
+pushdef([CFLAGS], CFLAGS_FOR_BUILD)dnl
+pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
+pushdef([LDFLAGS], LDFLAGS_FOR_BUILD)dnl
+pushdef([host], build)dnl
+pushdef([host_alias], build_alias)dnl
+pushdef([host_cpu], build_cpu)dnl
+pushdef([host_vendor], build_vendor)dnl
+pushdef([host_os], build_os)dnl
+pushdef([ac_cv_host], ac_cv_build)dnl
+pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
+pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
+pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
+pushdef([ac_cv_host_os], ac_cv_build_os)dnl
+pushdef([ac_cpp], ac_build_cpp)dnl
+pushdef([ac_compile], ac_build_compile)dnl
+pushdef([ac_link], ac_build_link)dnl
+
+save_cross_compiling=$cross_compiling
+save_ac_tool_prefix=$ac_tool_prefix
+cross_compiling=no
+ac_tool_prefix=
+
+AC_PROG_CC
+AC_PROG_CPP
+AC_EXEEXT
+
+ac_tool_prefix=$save_ac_tool_prefix
+cross_compiling=$save_cross_compiling
+
+dnl Restore the old definitions
+dnl
+popdef([ac_link])dnl
+popdef([ac_compile])dnl
+popdef([ac_cpp])dnl
+popdef([ac_cv_host_os])dnl
+popdef([ac_cv_host_vendor])dnl
+popdef([ac_cv_host_cpu])dnl
+popdef([ac_cv_host_alias])dnl
+popdef([ac_cv_host])dnl
+popdef([host_os])dnl
+popdef([host_vendor])dnl
+popdef([host_cpu])dnl
+popdef([host_alias])dnl
+popdef([host])dnl
+popdef([LDFLAGS])dnl
+popdef([CPPFLAGS])dnl
+popdef([CFLAGS])dnl
+popdef([CPP])dnl
+popdef([CC])dnl
+popdef([ac_objext])dnl
+popdef([ac_exeext])dnl
+popdef([ac_cv_objext])dnl
+popdef([ac_cv_exeext])dnl
+popdef([ac_cv_prog_cc_g])dnl
+popdef([ac_cv_prog_cc_cross])dnl
+popdef([ac_cv_prog_cc_works])dnl
+popdef([ac_cv_prog_gcc])dnl
+popdef([ac_cv_prog_CPP])dnl
+
+dnl Finally, set Makefile variables
+dnl
+BUILD_EXEEXT=$ac_build_exeext
+BUILD_OBJEXT=$ac_build_objext
+AC_SUBST(BUILD_EXEEXT)dnl
+AC_SUBST(BUILD_OBJEXT)dnl
+AC_SUBST([CFLAGS_FOR_BUILD])dnl
+AC_SUBST([CPPFLAGS_FOR_BUILD])dnl
+AC_SUBST([LDFLAGS_FOR_BUILD])dnl
+])
diff --git a/configure.ac b/configure.ac
index e4db0d44ed..03c3a5f928 100644
--- a/configure.ac
+++ b/configure.ac
@@ -69,6 +69,12 @@ AC_PROG_CXX
 AC_PROG_CPP
 AC_PROG_MKDIR_P
 
+# Set CC_FOR_BUILD (the *local* gcc to use for building e.g. lemon)
+if test "x$cross_compiling" = xno -a -z "$CC_FOR_BUILD"; then
+	CC_FOR_BUILD="$CC"
+fi
+AX_PROG_CC_FOR_BUILD
+
 dnl Work around libtool bug (fixed in the version 1.5a?)
 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
 AC_LIBTOOL_DLOPEN
@@ -228,13 +234,6 @@ if test "x$GCC" = "xyes" -o "x$CC" = "xclang" ; then
 	ac_supports_gcc_flags=yes
 fi
 
-if test "x$CC_FOR_BUILD" = x
-then
-       CC_FOR_BUILD=$CC
-fi
-AC_SUBST(CC_FOR_BUILD)
-AC_SUBST(CFLAGS_FOR_BUILD)
-
 # Check for doxygen
 AC_PATH_PROG(DOXYGEN, doxygen)
 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
@@ -3158,6 +3157,8 @@ AC_SUBST(WS_CFLAGS)
 AC_SUBST(WS_CXXFLAGS)
 AC_SUBST(WS_LDFLAGS)
 
+AC_SUBST(WS_CFLAGS_FOR_BUILD)
+
 dnl Save the cacheable configure results to config.cache before recursing
 AC_CACHE_SAVE
 
diff --git a/tools/lemon/Makefile.am b/tools/lemon/Makefile.am
index 0cafe51167..44ab0af4cd 100644
--- a/tools/lemon/Makefile.am
+++ b/tools/lemon/Makefile.am
@@ -23,25 +23,21 @@
 # is an archive library, any executable linking against libwireshark will
 # also need to link against libftypes.
 
+AUTOMAKE_OPTIONS = -Wno-gnu
+
 CC = $(CC_FOR_BUILD)
+CPPFLAGS = $(CPPFLAGS_FOR_BUILD)
+CFLAGS = $(CFLAGS_FOR_BUILD)
+LDFLAGS = $(LDFLAGS_FOR_BUILD)
+LIBS =
 
 if HAVE_WARNINGS_AS_ERRORS
-CFLAGS_FOR_BUILD += -Werror
+WERROR = -Werror
 endif
 
-LIBS =
-
 noinst_PROGRAMS = lemon
 
-lemon_SOURCES = lemon.c
-
-lemon_CPPFLAGS =
-
-lemon_CFLAGS = $(CFLAGS_FOR_BUILD)
-
-lemon_LDFLAGS = $(LDFLAGS_FOR_BUILD)
-
-lemon_LDADD =
+lemon_CFLAGS = $(WERROR) $(WS_CFLAGS_FOR_BUILD)
 
 CLEANFILES = \
 	*~